;;;-*-EMACS-LISP-*-
;;;
;;; Copyright 1988, 1989, 1990, 1991, 1992, 1993, 1994 Leigh L. Klotz, Jr.
;;; All Rights Reserved.
;;;

;;;
;;; M-x revert
;;;

(defun revert (arg)
  "Same as Revert Buffer, but doesn't ask about auto save versions unless
given an argument"
  (interactive "P")
  (revert-buffer (not arg)))

;;; M-x Buffer Search
;;; I put this on ^C ^B
;;;
(defun swap-windows ()
  "Swap the buffers displayed in two windows.
Like \\[other-window] except it switches the buffers, not the cursor."
  (interactive)
  (let ((buffer-a (current-buffer)))
    (other-window 1)
    (let ((buffer-b (current-buffer)))
      (switch-to-buffer buffer-a)
      (other-window 1)
      (switch-to-buffer buffer-b)))
  (other-window 1))

;;;
;;; M-X Buffer Search
;;;
;;; search for a string in all buffers.
;;; redo for next.

(defvar buffer-search-list nil)
(defvar buffer-search-string nil)

(defun buffer-search (string)
  "Search for a string through all buffers.
To continue, give an empty string or same string."
  (interactive "sString: ")
  (unless (or (string-equal string "")
	      (string-equal string buffer-search-string))
    (when (not (null buffer-search-list))
      (unless (y-or-n-p "Abort buffer search already in progress ")
	(error "")))
    (setq buffer-search-list (buffer-list))
    (setq buffer-search-string string))
  (buffer-search-continue))

(defun buffer-search-continue ()
  (let ((buffer-and-pos
	 (save-excursion
	   (catch 'buffer-search-found
	     (buffer-search-internal)
	     nil))))
    (when (null buffer-and-pos) (error "Not found"))
    (push buffer-and-pos buffer-search-list)
    (switch-to-buffer (car buffer-and-pos))
    (goto-char (cdr buffer-and-pos))))

(defun buffer-search-internal ()
  (save-excursion
    (while (not (null buffer-search-list))
      (let ((item (car buffer-search-list)))
	(setq buffer-search-list (cdr buffer-search-list))
	(let ((buffer (if (consp item) (car item) item))
	      (start-pos (if (consp item) (1+ (cdr item)) (point-min))))
	  (set-buffer buffer)
	  (goto-char start-pos)
	  (when (search-forward buffer-search-string (point-max) t)
	    (throw 'buffer-search-found (cons buffer (point)))))))
    (setq buffer-search-string nil)))